#!/usr/bin/perl

use strict;

use LWP::UserAgent;
use URI::URL;

my $VERSION = 0.1;

my ( 
    $title,
    $content, 
    $url,
   );

$title = "HTML Table Fixer";

print "Content-type: text/html\n\n";

unless ($url = $ENV{PATH_INFO}) {
    print "This program will present you an HTML document 
	   with its TABLE and TD tags stripped of absolute
	   widths.  Call this URL again, and append the URL of the 
	    desired document\n";
    exit;
} 


for ($url) {
    s,^/(?=[^/]),//,;
    s,^/*http:,,i;
    if ( /^(\w+):/ )  {
	if ( "\U$1" ne "HTTP") {
	    print "<h1>Error</H1>", "Bad URL:",
		    "You must specify an http URL only\n";
	    exit;
	} 
    } else {
	s/^/http:/;
    } 
} 

my $ua = new LWP::UserAgent;
$ua->agent("$0/$VERSION " . $ua->agent);

my $req = HTTP::Request->new(GET => $url);
$req->header('Accept' => 'text/html');

# send request
my $res = $ua->request($req);

# check the outcome
if ($res->is_success) {
    $content = $res->content;
} else {
    print ("<H1>Error</H1>");
    print "Can't fetch <I>$url</I>: <TT>", $res->code, " ", $res->message;
    exit;
}

my $u = URI::URL->new($url);
my ($site, $prepath);
$site = $u->host();
($prepath = $url) =~ s,/[^/]*$,,;

for ($content) {

    if ($url =~ /\bcnn\b/) {

	s{<![^>]*search.and.promos.*?(?=<!)}{}gsi;
	s{<![^>]*search\s+-\s+replace.*?/search.*?>}{}gsi;
	s{<!--=+\s*search.*?<center>.*?</center>}{}gsi;
	s{<A HREF[^>]*redir.*?</a>}{}gsi;

	for my $crap (qw(
			    ADS
			    CNN.SI
			    SPONSORS 
			    POINTCAST
			    AIRMEDIA
			    spotlight
			    CustomNews
		     )
		 )
	{
	    s{<!--[^>\w]*$crap[^>]*>.*?<!--[^>]*/?$crap[^>]*>}{}gsi;
	    #s{<!--[^>\w]*$crap[^>]*>.*?<!--[^>]*>}{}gsi;
	} 

	for my $section ( 'CustomNews', 'Jobs', 'Feedback', 'Pager', 'CNN ON-AIR', 'SPECIALS', 'VIEWS' ) {
	    #next;
	    s{(<![^>]+$section Bullets[^>]+).*?\1}{}si;
	} 

	s{<A\s*HREF[^>]+>\s*<img[^>]*src\s*=\s*"/ads/[^>]*>\s*</a>}{}gi;
	s{<img[^>]*src\s*=\s*"/ads/[^>]*>\s*}{}gi;

    }

    s{
	(
	  < #  abigail says no \s* here
	  (?: TABLE | TD | TR | HR )
	  [^>]*?
	)
	  \s* BGCOLOR \s* = \s* [^>\s]+
    }{$1}gsxi; 

    s{
	(
	  < #  abigail says no \s* here
	  (?: TABLE | TD | TR | HR )
	  [^>]*?
	)
	  \s* WIDTH \s* = \s* 
	  (?: (?: (["'])? (?: \d+ ) \2 ) | \d+ )
	  \s*
	  (?!%)
	  (?=[\s>])
    }{$1}gsxi; 

    s{<FONT[^>]*>}{}gi;


    #s{href\s*=\s*"(?!/)}{HREF="http://$url}gi;
    s{href\s*=\s*"/}{HREF="http://$site/}gi;
    s{http:}{http://cgi.perl.com/cgi-bin/refmt/http:}gi;

    s{(<HEAD[^>]*>)}{$1\n<BASE HREF="$url">}i
	||
    s{^}{\n<BASE HREF="$url"};

    print;
}